本篇教程由作者设定使用 CC BY-NC 协议。

    本教程旨在介绍Sakura的酒类/茶类系统，并分享一个笔者自制的Tooltip脚本。

    众所周知，Sakura提供了一套酒类系统，然而其只有单纯的合成表但没说明详细效果，各种鸡尾酒纷繁复杂的合成步骤也劝退了许多玩家，故而笔者写下这篇教程介绍这个系统。但在此之前有一点必须声明的是：


现实生活中请适度饮酒，未成年人禁止饮酒！！


    Sakura的酒类和茶都可以提供一定的buff。对于酒类来说，它固定提供30s的反胃debuff以及一些额外的buff（也有提供debuff的，比如说亚历山大、飞行和什锦鸡尾酒），而对于茶类来说它只会提供固定的buff。重复饮酒可以延长buff额外时间（包括debuff）并重置反胃debuff时间，而重复饮茶则会延长其提供的buff时间。也正因如此，笔者选择将茶类纳入Sakura的酒类系统中，尽管二者在制作和buff提供上存在一定差异。

一、基酒

    1.1.基酒介绍

    基酒，即是鸡尾酒中的作为基底的酒。Sakura提供了15种基酒，它们都可以通过蒸馏、酿造或者购买的方式获得。其详细信息如下：

名称液体原料物品原料制作方式食用后获得的额外buff
啤酒水小麦、酵母、啤酒花酿造10s饱和I
浊酒水熟米饭、酵母酿造10s抗性提升I
清酒浊酒-酿造20s抗性提升I、5s生命恢复I
烧酒清酒-蒸馏30s抗性提升I、10s生命恢复I
红葡萄酒葡萄汁糖、酵母酿造20s夜视
白葡萄酒绿葡萄汁糖、酵母酿造20s夜视
香槟白葡萄酒糖、酵母酿造30s夜视II
朗姆酒水甘蔗蒸馏20s水下呼吸
伏特加水土豆蒸馏20s力量I
威士忌水各种谷物蒸馏20s急迫I
白兰地葡萄汁/绿葡萄汁糖蒸馏20s急迫I

琴酒

（金酒、杜松子酒）

N/AN/A购买*20s急迫I
龙舌兰N/AN/A购买*20s急迫I
利口酒朗姆酒/伏特加/威士忌/白兰地糖、各种水果蒸馏20s跳跃提升I
可可利口酒朗姆酒/伏特加/威士忌/白兰地糖、可可豆蒸馏20s跳跃提升I

    注：

    *这两种酒只能通过购买获得，不能自己制作。

    

    1.2.获取方式：蒸馏和酿造

    蒸馏和酿造是制作绝大部分基酒的方法。蒸馏需要蒸馏桶，而酿造需要酿造桶，二者的合成配方如下：

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第1张图片蒸馏桶合成配方[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第2张图片酿造桶合成配方

    酿造桶放入原料后就可以工作，而蒸馏桶则需要下方放入热源方块才能工作，如火或者熔岩（包括流动的），如下：

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第3张图片两种可行的加热方式

    值得注意的是：除啤酒和利口酒/可可利口酒外，大部分可制作基酒的配方都是 液体原料200mb+各种物品原料1份→成品酒100mb ，而酿造桶/蒸馏桶的液体原料栏和产物栏都是3000mb，1.12.2的Sakura在UI上仍然存在“移动鼠标显示液体含量”和“可以用容器右键酿造桶直接舀出产物”的巨大优化空间，而酒类一般都需要1000mb才能通过容器从右边UI导出，这就导致玩家常常在填满一个酿造桶原料槽后合成1500mb的酒类、剩下500mb酒残余无法导出的情况，笔者给出的建议是：要么控制加入原料使其刚好凑满1000mb，要么再加入原料使其酿造满3000mb。

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第4张图片3000mb水酿出1500mb酒

    这里说一个注意事项：由于1.12.2的Sakura模组物品“储藏桶”存在“修复因放入带有酒的酒瓶试图导出其中液体酒时导致在游戏程序运行至cn.mcmod.sakura.inventory.ContainerFluidOut类的成员函数transferStackInSlot()下mergeItemStack()函数时，因传入的第三个参数（38）大于玩家物品栏格子数（36）+容器槽位数（2）合并后的格子数组最大index数（37）而发生数组越界的小问题，并最终导致客户端崩溃但可以几乎无损回档”的、不影响游戏存档和不使用该操作下不会破坏游戏体验时的小小优化空间，所以这里笔者强烈建议无视掉“储液桶”这个容器。不过这又会引出另一个问题：储存在桶里的酒和空瓶的酒没法相互转换。在不考虑魔改补充合成配方的前提下，笔者给出的建议是：在导出酒时优先考虑是否需要进一步加工（需要的优先用桶储存），而后考虑用空瓶罐装储存（绝对不是笔者懒得去搓合成表的魔改代码！）。不要使用酒杯直接导出，那样1000mb只会给你1杯酒，性价比很低！

    [MC版本:1.12.2，Sakura模组版本：1.0.7-1.12.2]

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第5张图片崩溃报告

    P.S.笔者亲自去B站询问模组作者，他表示：已经放弃1.12.2了

    有了酒瓶还不能直接喝，用空杯子和酒瓶合成一下就可以把酒倒出来饮用了。每瓶酒可以倒出5杯酒，倒完后返回空瓶。只是空杯子只有很低的概率返还。为了解决这个问题，可以考虑添加下边的CrT魔改代码：（只是有时候会给你两个杯子（）

import crafttweaker.player.IPlayer;
import crafttweaker.item.IItemStack;

events.onEntityLivingUseItemFinish(function(event as crafttweaker.event.EntityLivingUseItemEvent.Finish){
    if(!event.isPlayer||event.player.world.remote)return;
    var player as IPlayer = event.player;
    var item as IItemStack = event.item;
    if(
        !isNull(item)&&(
            <item:sakura:alcoholic:*>.matches(item)||
            <item:sakura:cocktail:*>.matches(item)||
            <item:sakura:cocktail:*>.matches(item)
        )
    ){
        player.give(<item:sakura:cup>*1);
    }
});


    

    1.3.获取方式：购买

    交易！把你酿造的基酒卖给酒贩！我敢打赌，这绝对是最赚钱的生意，没有之一！

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第6张图片一名酒贩

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第7张图片一瓶朗姆酒半组钱（堆叠效果是StackUp!魔改的）

    你可以和酒贩（一种Sakura添加的新村民职业）交易到所有种类的基酒，同时酒贩也会收购所有种类的基酒，只是一开始，酒贩都很挑，他们只交易四种酒——不过一旦解锁了容易制作的朗姆酒、伏特加、威士忌，你就可以享受樱花钱币的财富自由了！

村民等级出售物品
1啤酒、浊酒、红葡萄酒、白葡萄酒
2清酒、香槟
3烧酒、朗姆酒、伏特加、威士忌、白兰地
4琴酒、龙舌兰、利口酒、可可利口酒


二、鸡尾酒

    2.1.鸡尾酒介绍

    Sakura添加了41种鸡尾酒，这些鸡尾酒都具有其现实原型，其中部分能够提供Sakura独特的药水效果。各种鸡尾酒详细信息如下：

    注：笔者并非专业调酒师/鸡尾酒爱好者，大多数信息来自于百度百科，部分百度百科未收录的则使用了WikiPEDIA（注意需要科学上网），并根据B站知名调酒师up红斌-调酒的아저씨的视频校正。不保证非科普内容部分不夹带私货

    做完表格后笔者血压已经拉满了......笔者表示可能还存在更多的错误，等笔者后续查验更新吧

名称杯装基酒瓶装基酒其它原料食用后获得的额外buff备注
基尔酒利口酒白葡萄酒黑加仑汁10s经验提升I、10s夜视原名KIR
皇家基尔酒香槟白葡萄酒黑加仑汁10s经验提升I、20s夜视II

原名KIR ROYAL

注：经过查证皇家基尔酒用的是

香槟（而不是白葡萄酒）加在黑加仑利口酒上

百毒百科和这里都错了（信息来源）

玛格丽塔龙舌兰利口酒柠檬汁10s速度I、10s抗火

原名Margarita，也叫玛格丽特

被誉为“鸡尾酒之后”

是马天尼外最知名的鸡尾酒之一，拥有丰富的变种

天堂琴酒利口酒橙汁

10s速度I、10s抗火、

0.1s瞬间治疗

原名Paradise

也叫天堂乐园

注：经过查证，天堂是使用琴酒（金酒、杜松子酒）

杏仁白兰地、橙汁以2:1:1的比例调配而成

并添加少量柠檬汁，没有使用利口酒（信息来源）

边车白兰地利口酒柠檬汁10s急迫I、0.1s金色生命I

原名Side Car

曾经是世界上最昂贵的鸡尾酒

“鸡尾酒十杰”之一

法式七五白兰地香槟柠檬汁、[糖]10s大炮I

原名French 75

也叫法兰西75，一款以野战火炮命名的鸡尾酒

注：经过查证，法兰西七五的基酒是香槟和

杜松子酒，不含白兰地（信息来源）

约翰科林白兰地-

柠檬汁、苏打水

[糖]

10s急迫I、10s抗性提升I

也叫约翰柯林斯

汤姆柯林斯（Tom Collins）的旧称

注：经过查证，约翰柯林斯/汤姆柯林斯是以

杜松子酒为基酒，不含白兰地（信息来源）

德贵丽朗姆酒-柠檬汁、[糖]10s水下呼吸I、10s抗性提升I

原名Daiquiri

也叫戴吉利、得其利、冻唇蜜

床笫（zǐ）之间朗姆酒

白兰地

利口酒

柠檬汁10s急迫I、10s火焰之刃I

原名Between the Sheets

（注：“床笫之间”原意泛指床铺）

黑俄伏特加利口酒-10s力量I、10s火焰之刃I

原名Black Russian

全称黑俄罗斯

教父威士忌利口酒杏仁*10s急迫I、10s经验提升I

原名Godfather

教母伏特加利口酒杏仁*10s力量I、10s经验提升I

原名Godmother

教父的衍生鸡尾酒之一

（其余衍生品还有French Connection

“法国贩毒网”鸡尾酒

和Godchild一家人就要整整齐齐）

草蚱蜢利口酒-

牛奶

薄荷、柠檬汁

10s速度I、10s跳跃提升I

原名Grasshopper

也叫绿色蚱蜢、青草蜢

注：绿色蚱蜢由薄荷甜酒和可可甜酒调配而成

笔者认为这里应该将可可利口酒加入配方更合适

（信息来源）

薄荷朱利普威士忌-

水

薄荷、糖

10s速度I、10s急迫I

原名Mint Julep

莫吉托朗姆酒-

薄荷、柠檬汁

苏打水、糖

10s速度I、10s急迫I、

10s夜视

原名Mojito

世界上最著名的鸡尾酒之一

锈钉

朗姆酒

利口酒

--10s幸运I、10s急迫I

原名Rusty Nail

也叫生锈钉

注：经过查证，锈钉是苏格兰威士忌和

苏格兰威士忌利口酒以1:1到2:1的比例调配而成

不含朗姆酒（信息来源）

柠檬玛格丽塔龙舌兰利口酒柠檬汁、柠檬20s速度II、20s抗火II玛格丽塔的变种之一
俄罗斯之春伏特加利口酒

黑加仑汁

柠檬汁、糖

10s生命恢复I

10s力量I、10s跳跃提升I

原名Russian Spring Punch

也叫俄罗斯春季宾治

亚历山大白兰地利口酒牛奶10s生命恢复I、10s饥饿II

原名Alexander

又称“亚历珊朵拉”

注：亚历山大是由法国白兰地、

可可甜酒、奶油调配而成

笔者认为这里基酒原料选用可可利口酒更合适

（信息来源）

飞行琴酒白兰地柠檬汁10s速度I、5s漂浮I

原名Aviation

也叫“云霄”

注：经过查证，飞行是由杜松子酒、黑樱桃利口酒、

荷兰紫罗兰利口酒搭配柠檬汁调配而成

并没有用到白兰地（信息来源）

波菲利普白兰地红葡萄酒

鸡蛋

10s急迫I、10s夜视

原名Porto Flip

也叫波特霏丽蒲

红眼伏特加啤酒番茄酱、糖10s生命提升I、10s夜视

血腥凯撒（Bloody Caesar/Caesar）的变种之一

原名Red Eye

注：血腥凯撒是由伏特加、蛤肉番茄汁、辣酱、

伍斯特酱调配而成，并将杯沿蘸上香芹盐霜、

辅以西芹和锲入杯沿的柠檬片作装饰物。

将基酒伏特加替换成啤酒的衍生种

常常被称为“红眼”，故而笔者认为

此处配方应该加上伍斯特酱、删去伏特加。

（信息来源）

汽酒

（原型应为斯普瑞兹）

红/白葡萄酒-苏打水20s夜视

原名Spritzer，译为“斯普瑞兹”

注：经查证“汽酒（起泡酒）/Sparling Wine”

是一类含大量二氧化碳的酒的代称

典型代表就是香槟

而Spritzer则指用白葡萄酒添加苏打水调配的鸡尾酒

什锦鸡尾酒

（原型应为柠檬汽酒）

啤酒-柠檬汁、糖10s饱和、5s漂浮I

原名Panaché，译为“柠檬汽酒”

属于酒类饮品Shandy的一种

血腥玛丽伏特加-橙汁*20s力量II

原名Bloody Mary

这是一个在西方非常流行的词汇

其知名度最早便来自于该鸡尾酒

（具体请参见百度百科）

注：现实中人们在调配时会往其中添加

黑胡椒、辣椒粉、酱油、柠檬、

大量TABASCO辣椒面等刺激性调料以增加其风味

故而笔者强烈怀疑其配方和下面螺丝刀写反了

喝了不能让你攻击生物时百分比增伤

并概率掉落凝血

螺丝刀伏特加-

番茄酱、柠檬汁

盐、黑胡椒

10s生命提升I、10s力量I

10s伤害吸收I

原名Screwdriver，也叫螺丝起子

因其添加的橙汁掩盖了高度数伏特加的特征

特别容易将女士灌醉，号称“女士杀手”

请各位不胜酒力的女士记得保护好自己！

注：现实中螺丝刀的原料仅有伏特加、橙汁

和冰块，故而笔者强烈怀疑其配方和上面

血腥玛丽写反了

清酒马提尼清酒利口酒-

10s生命提升I

10s生命恢复I

0.1s瞬间治疗I

马天尼原名Martini，也叫马提尼

世界上最著名的鸡尾酒，号称“鸡尾酒之王”

和玛格丽塔一样，马天尼也拥有许多衍生酒

清酒马天尼（Saketini）便是日本风味的衍生酒之一

（尽管它并非真正意义上的马天尼）（信息来源）

酒鬼炸弹啤酒威士忌-10s饱和I、10s急迫I

原名Boilermaker

也叫锅炉厂鸡尾酒

注：经过查证，Boilermaker同时可以指代两种

以啤酒为基酒的鸡尾酒。在美国，Boilermaker

的配方为威士忌和啤酒；而在英国，Boilermaker

的配方则是爱尔轻啤酒和棕色爱尔啤酒。（信息来源）

啤酒玛格丽塔啤酒利口酒柠檬汁10s饱和I、10s速度I玛格丽塔的变种之一
长岛冰茶龙舌兰

伏特加

朗姆酒

琴酒

利口酒

柠檬汁、可可豆10s金色生命I

原名Long Island Iced Tea

也叫“失身酒”、“一杯倒”

一款度数很高的鸡尾酒（约35度）

请各位不胜酒力的女士记得保护好自己！

「这是茶，不是酒」

海波威士忌-苏打水20s急迫I

海波（Highball）是一类以高度数基酒搭配大量

非酒精类饮品（通常是碳酸饮料）制成的鸡尾酒，

包含螺丝起子、汤姆柯林斯等。

海波在日本非常流行，其中ハイボール（haibōru）

一词专门指代威士忌+柠檬水制成的海波

也是游戏中该酒的原型

不是硫代硫酸钠

传送走廊朗姆酒-

薄荷、柠檬汁

苏打水

10s饱和I、10s急迫I

10s力量I

原名Porchcrawler，也叫Porchclimb

毒刺白葡萄酒利口酒薄荷10s毒药I

原名Stinger，直译为“毒刺”、“讽刺者”

也叫史汀格、史丁格，一款曾经流行的鸡尾酒

尼格罗尼琴酒

红葡萄酒

利口酒

-

10s抗性提升I

5s金色生命I

原名Negroni，也叫尼克洛尼
古典鸡尾酒威士忌朗姆酒

糖、水

10s速度I、10s急迫I

10s夜视

原名Old Fashioned，也叫古典酒、老式酒

其拥有专门的杯子“古典杯”

是鸡尾酒常用的容器之一

威士忌酸威士忌-柠檬汁、糖10s速度I、10s急迫I

原名Whisky Sour，也叫威士忌沙瓦

短饮鸡尾酒的一种

琴蕾琴酒-

柠檬汁、苏打水

20s速度I、20s急迫I原名Gimlet，也叫吉姆雷特
龙舌兰日出龙舌兰-橙汁*、糖10s速度I、0.1s瞬间治疗I原名Tequila Sunrise，也叫特基拉日出
飞蝗啤酒利口酒薄荷、柠檬汁10s速度II、10s跳跃提升I

原名Flying Grasshopper，也叫飞天蚱蜢

注：实际飞天蚱蜢是由绿色蚱蜢的奶水

换成伏特加以达到更烈性的口感

因此笔者强烈怀疑配方的啤酒写错了

蛋奶酒威士忌-

牛奶、鸡蛋

糖

10s蝎毒I

原名Eggnog，也叫蛋酒，圣诞节代表性饮品

注：笔者强烈怀疑作者少写了蛋奶酒的buff

导致天蝎和莫斯科骡子的buff移位了

分别给到了蛋奶酒和天蝎上

天蝎白兰地朗姆酒

柠檬汁、橙汁*

糖

10s饱和I、10s力量I

原名Scorpion，也叫天蝎座

天蝎给不了蝎毒，蛋奶却可以[捂脸]

莫斯科骡子伏特加-

柠檬汁、柠檬

苏打水

无

对，你没看错！

实测这个酒反复饮用

只会刷新30s反胃debuff

原名Moscow Mule

也叫莫斯科之骡、莫斯科佬

    注：

    *这些材料无法通过原版Sakura模组在生存中获取，可用其他模组同矿辞材料代替。


    当然，这么多信息却没有在游戏里显示，这多不方便啊！因此笔者用CrT做了一个显示这些信息的Tooltips的脚本，效果如下：

[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第8张图片基酒酒杯效果[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第9张图片基酒瓶效果
[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第10张图片鸡尾酒效果1[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第11张图片鸡尾酒效果2
[1.12.2]酒类系统介绍和酒类Tooltip脚本分享-第12张图片茶类效果


    食用方法：下载CrT模组，下载脚本文件：链接，提取码：p5cs，而后把脚本扔进游戏的.minecraft\scripts或者.minecraft\versions\<你的游戏版本名字>\scripts文件夹中；或者手动创建脚本：用一个新的文本文件将下文代码复制进去，保存，改文本文件后缀为.zs，然后扔进上述目录中即可。

    相关代码如下：

//Extra Tooltips for Sakura
//By JackStuart

import crafttweaker.data.IData;
import crafttweaker.item.IItemStack;

var introduce as string = "";
//==========各种茶==========
//红茶
introduce = "§r由红茶茶叶泡制而成";
<sakura:tea:0>.addTooltip(introduce);
<sakura:tea:0>.addTooltip("§r·饮下后获得"~stringEffect("0.05","瞬间治疗")~"buff");

//绿茶
introduce = "§r由绿茶茶叶泡制而成";
<sakura:tea:1>.addTooltip(introduce);
<sakura:tea:1>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"急迫I")~"buff");

//奶茶
introduce = "§r由红茶茶叶和牛奶泡制而成";
<sakura:tea:2>.addTooltip(introduce);
<sakura:tea:2>.addTooltip("§r·饮下后获得"~stringEffect("0.05","瞬间治疗")~"和"~stringEffectInt(10,"生命恢复I")~"buff");

//奶绿
introduce = "§r由绿茶茶叶和牛奶泡制而成";
<sakura:tea:3>.addTooltip(introduce);
<sakura:tea:3>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命恢复")~"和"~stringEffectInt(30,"急迫")~"buff");

//伯爵茶
introduce = "§r由伯爵茶叶泡制而成";
<sakura:tea:4>.addTooltip(introduce);
<sakura:tea:4>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"水下呼吸")~"buff");

//伯爵奶茶
introduce = "§r由伯爵茶叶和牛奶泡制而成";
<sakura:tea:5>.addTooltip(introduce);
<sakura:tea:5>.addTooltip("§r·饮下后获得"~stringEffectInt(60,"水下呼吸II")~"buff");

//果茶
introduce = "§r由果茶茶叶泡制而成";
<sakura:tea:6>.addTooltip(introduce);
<sakura:tea:6>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"跳跃提升")~"buff");

//水果奶茶
introduce = "§r由果茶茶叶和牛奶泡制而成";
<sakura:tea:7>.addTooltip(introduce);
<sakura:tea:7>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"跳跃提升")~"和"~stringEffectInt(10,"生命恢复")~"buff");

//柠檬红茶
introduce = "§r由柠檬和红茶茶叶泡制而成";
<sakura:tea:8>.addTooltip(introduce);
<sakura:tea:8>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"速度I")~"和"~stringEffect("0.05","瞬间治疗")~"buff");

//柠檬绿茶
introduce = "§r由柠檬和绿茶茶叶泡制而成";
<sakura:tea:9>.addTooltip(introduce);
<sakura:tea:9>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"急迫I")~"和"~stringEffectInt(20,"速度I")~"buff");

//薄荷茶
introduce = "§r由薄荷茶茶叶泡制而成";
<sakura:tea:10>.addTooltip(introduce);
<sakura:tea:10>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"夜视")~"buff");

//大麦茶
introduce = "§r由谷物（小麦、大米、荞麦等）泡制而成";
<sakura:tea:11>.addTooltip(introduce);
<sakura:tea:11>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"抗性提升")~"buff");

//糙米茶
introduce = "§r由玄米茶茶叶泡制而成";
<sakura:tea:12>.addTooltip(introduce);
<sakura:tea:12>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"生命恢复")~"buff");



<sakura:tea:*>.addTooltip("§r·重复使用以§a§o延长§rbuff时间");


//==========基础酒==========
//啤酒
introduce = "§r由水加小麦、酵母和啤酒花§e酿造§r而成的一种常见酒";
<sakura:bottle_alcoholic:0>.addTooltip(introduce);
<sakura:alcoholic:0>.addTooltip(introduce);
<sakura:alcoholic:0>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和")~"和30s§c反胃§rbuff");

//浊酒
introduce = "§r由水加熟米饭和酵母§e酿造§r而成的一种半成品酒";
<sakura:bottle_alcoholic:1>.addTooltip(introduce);
<sakura:alcoholic:1>.addTooltip(introduce);
<sakura:alcoholic:1>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"抗性提升I")~"和30s§c反胃§rbuff");

//清酒
introduce = "§r由浊酒§e酿造§r而成的一种常见酒";
<sakura:bottle_alcoholic:2>.addTooltip(introduce);
<sakura:alcoholic:2>.addTooltip(introduce);
<sakura:alcoholic:2>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"抗性提升I")~"、"~stringEffectInt(5,"生命恢复I")~"和30s§c反胃§rbuff");

//烧酒
introduce = "§r由清酒进一步§e蒸馏§r而成的一种常见酒，别名白酒";
<sakura:bottle_alcoholic:3>.addTooltip(introduce);
<sakura:alcoholic:3>.addTooltip(introduce);
<sakura:alcoholic:3>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"抗性提升I")~"、"~stringEffectInt(10,"生命恢复I")~"和30s§c反胃§rbuff");

//红葡萄酒
introduce = "§r由葡萄汁加糖和酵母§e酿造§r而成的一种常见酒";
<sakura:bottle_alcoholic:4>.addTooltip(introduce);
<sakura:alcoholic:4>.addTooltip(introduce);
<sakura:alcoholic:4>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"夜视")~"和30s§c反胃§rbuff");

//白葡萄酒
introduce = "§r由绿葡萄汁加糖和酵母§e酿造§r而成的一种常见酒";
<sakura:bottle_alcoholic:5>.addTooltip(introduce);
<sakura:alcoholic:5>.addTooltip(introduce);
<sakura:alcoholic:5>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"夜视")~"和30s§c反胃§rbuff");

//香槟
introduce = "§r由§c白§r葡萄酒加糖和酵母进一步§e酿造§r而成的一种高级酒";
<sakura:bottle_alcoholic:6>.addTooltip(introduce);
<sakura:alcoholic:6>.addTooltip(introduce);
<sakura:alcoholic:6>.addTooltip("§r·饮下后获得"~stringEffectInt(30,"夜视II")~"和30s§c反胃§rbuff");

//朗姆
introduce = "§r由水加甘蔗§e蒸馏§r而成的一种酒";
<sakura:bottle_alcoholic:7>.addTooltip(introduce);
<sakura:alcoholic:7>.addTooltip(introduce);
<sakura:alcoholic:7>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"水下呼吸")~"和30s§c反胃§rbuff");

//伏特加
introduce = "§r由水加土豆§e蒸馏§r而成的一种酒";
<sakura:bottle_alcoholic:8>.addTooltip(introduce);
<sakura:alcoholic:8>.addTooltip(introduce);
<sakura:alcoholic:8>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"力量I")~"和30s§c反胃§rbuff");

//威士忌
introduce = "§r由水加谷物（小麦、大米、荞麦等）§e蒸馏§r而成的一种酒";
<sakura:bottle_alcoholic:9>.addTooltip(introduce);
<sakura:alcoholic:9>.addTooltip(introduce);
<sakura:alcoholic:9>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//白兰地
introduce = "§r由红/白葡萄汁加糖§e蒸馏§r而成的一种酒";
<sakura:bottle_alcoholic:10>.addTooltip(introduce);
<sakura:alcoholic:10>.addTooltip(introduce);
<sakura:alcoholic:10>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//琴酒
introduce = "§r一种用包括杜松子在内的植物香源浸提或串香复蒸馏制成的蒸馏酒，又称金酒、杜松子酒";
<sakura:bottle_alcoholic:11>.addTooltip(introduce);
<sakura:bottle_alcoholic:11>.addTooltip("§b·只能通过酒贩购买获得");
<sakura:alcoholic:11>.addTooltip(introduce);
<sakura:alcoholic:11>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//龙舌兰
introduce = "§r一种以龙舌兰为原料，经发酵、蒸馏、陈酿、调配而成的蒸馏酒";
<sakura:bottle_alcoholic:12>.addTooltip(introduce);
<sakura:bottle_alcoholic:12>.addTooltip("§b·只能通过酒贩购买获得");
<sakura:alcoholic:12>.addTooltip(introduce);
<sakura:alcoholic:12>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//利口酒
introduce = "§r由朗姆酒/白兰地/伏特加/威士忌加糖和各种水果§e蒸馏§r而成的一种酒精饮料";
<sakura:bottle_alcoholic:13>.addTooltip(introduce);
<sakura:alcoholic:13>.addTooltip(introduce);
<sakura:alcoholic:13>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"跳跃提升I")~"和30s§c反胃§rbuff");

//可可利口酒
introduce = "§r由朗姆酒/白兰地/伏特加或威士忌加糖和可可豆§e蒸馏§r而成的一种蒸馏酒";
<sakura:bottle_alcoholic:14>.addTooltip(introduce);
<sakura:alcoholic:14>.addTooltip(introduce);
<sakura:alcoholic:14>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"跳跃提升I")~"和30s§c反胃§rbuff");

<sakura:bottle_alcoholic:*>.addTooltip("§4§l现实中请适量饮酒！未成年人禁止饮酒！！");
<sakura:alcoholic:*>.addTooltip("§r·重复使用以§a§o延长§rbuff时间并§e§o重置§r§c反胃§r效果");
<sakura:alcoholic:*>.addTooltip("§4§l现实中请适量饮酒！未成年人禁止饮酒！！");

//==========鸡尾酒==========
//基尔酒
introduce = "§r由黑加仑汁、白葡萄酒和利口酒调配而成的著名法国鸡尾酒";
<sakura:cocktail:0>.addTooltip(introduce);
<sakura:cocktail:0>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"经验提升I")~"、"~stringEffectInt(10,"夜视")~"和30s§c反胃§rbuff");

//皇家鸡尾酒
introduce = "§r一种著名的法国鸡尾酒，游戏中由黑加仑汁、香槟和利口酒调配而成（实际配方为黑加仑利口酒和香槟）";
<sakura:cocktail:1>.addTooltip(introduce);
<sakura:cocktail:1>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"经验提升I")~"、"~stringEffectInt(20,"夜视II")~"和30s§c反胃§rbuff");

//玛格丽塔
introduce = "§r由柠檬汁、龙舌兰和利口酒调配而成的著名传统鸡尾酒，也叫玛格丽特";
<sakura:cocktail:2>.addTooltip(introduce);
<sakura:cocktail:2>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffectInt(10,"抗火")~"和30s§c反胃§rbuff");

//天堂
introduce = "§r由橙汁、琴酒和利口酒调配而成的著名鸡尾酒，也叫天堂乐园";
<sakura:cocktail:3>.addTooltip(introduce);
<sakura:cocktail:3>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffectInt(10,"抗火")~"、"~stringEffect("0.1","瞬间治疗")~"和30s§c反胃§rbuff");

//边车
introduce = "§r由柠檬汁、白兰地和利口酒调配而成的著名鸡尾酒，";
<sakura:cocktail:4>.addTooltip(introduce);
<sakura:cocktail:4>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"急迫I")~"、"~stringEffect("0.1","金色生命I")~"和30s§c反胃§rbuff");

//法式七五
introduce = "§r由柠檬汁、糖、白兰地和香槟调配而成的著名鸡尾酒";
<sakura:cocktail:5>.addTooltip(introduce);
<sakura:cocktail:5>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"大炮I")~"和30s§c反胃§rbuff");

//约翰柯林斯
introduce = "§r由柠檬汁、糖、苏打水和白兰地调配而成的著名鸡尾酒，现在叫做汤姆柯林斯";
<sakura:cocktail:6>.addTooltip(introduce);
<sakura:cocktail:6>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"急迫I")~"、"~stringEffect("10","抗性提升I")~"和30s§c反胃§rbuff");

//德贵丽
introduce = "§r由柠檬汁、糖和朗姆酒调配而成的著名鸡尾酒，也叫戴吉利、得其利、冻唇蜜";
<sakura:cocktail:7>.addTooltip(introduce);
<sakura:cocktail:7>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"水下呼吸I")~"、"~stringEffect("10","抗性提升I")~"和30s§c反胃§rbuff");

//床笫之间
introduce = "§r由柠檬汁、朗姆酒、白兰地酒和利口酒调配而成的经典鸡尾酒";
<sakura:cocktail:8>.addTooltip(introduce);
<sakura:cocktail:8>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"急迫I")~"、"~stringEffect("10","火焰之刃I")~"和30s§c反胃§rbuff");

//黑俄罗斯
introduce = "§r由伏特加和利口酒调配而成的经典鸡尾酒，全名黑俄罗斯";
<sakura:cocktail:9>.addTooltip(introduce);
<sakura:cocktail:9>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"力量I")~"、"~stringEffect("10","火焰之刃I")~"和30s§c反胃§rbuff");

//教父
introduce = "§r由杏仁、威士忌和利口酒调配而成的经典鸡尾酒";
<sakura:cocktail:10>.addTooltip(introduce);
<sakura:cocktail:10>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"急迫I")~"、"~stringEffect("10","经验提升I")~"和30s§c反胃§rbuff");

//教母
introduce = "§r由杏仁、伏特加和利口酒调配而成的经典鸡尾酒，教父的衍生酒之一";
<sakura:cocktail:11>.addTooltip(introduce);
<sakura:cocktail:11>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"力量I")~"、"~stringEffect("10","经验提升I")~"和30s§c反胃§rbuff");

//草蚱蜢
introduce = "§r由柠檬汁、牛奶、薄荷和利口酒调配而成的经典鸡尾酒，也叫绿色蚱蜢、青草蜢";
<sakura:cocktail:12>.addTooltip(introduce);
<sakura:cocktail:12>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffect("10","跳跃提升I")~"和30s§c反胃§rbuff");

//薄荷朱利普
introduce = "§r由水、糖、薄荷和威士忌调配而成的经典鸡尾酒";
<sakura:cocktail:13>.addTooltip(introduce);
<sakura:cocktail:13>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffect("10","急迫I")~"和30s§c反胃§rbuff");

//莫吉托
introduce = "§r由柠檬汁、糖、薄荷、苏打水和朗姆酒调配而成的著名鸡尾酒";
<sakura:cocktail:14>.addTooltip(introduce);
<sakura:cocktail:14>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffect("10","急迫I")~"、"~stringEffect("10","夜视")~"和30s§c反胃§rbuff");

//锈钉
introduce = "§r由朗姆酒和利口酒调配而成的著名鸡尾酒，也叫生锈钉";
<sakura:cocktail:15>.addTooltip(introduce);
<sakura:cocktail:15>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"幸运I")~"、"~stringEffect("10","急迫I")~"和30s§c反胃§rbuff");

//柠檬玛格丽塔
introduce = "§r由柠檬、柠檬汁、龙舌兰和利口酒调配而成的著名传统鸡尾酒，玛格丽塔的变种之一";
<sakura:cocktail:16>.addTooltip(introduce);
<sakura:cocktail:16>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"速度II")~"、"~stringEffectInt(20,"抗火II")~"和30s§c反胃§rbuff");

//俄罗斯之春
introduce = "§r由柠檬汁、黑加仑汁、糖、伏特加和利口酒调配而成的传统鸡尾酒";
<sakura:cocktail:17>.addTooltip(introduce);
<sakura:cocktail:17>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命恢复I")~"、"~stringEffectInt(10,"抗性提升I")~"、"~stringEffect("10","力量I")~"和30s§c反胃§rbuff");

//亚历山大
introduce = "§r由牛奶、白兰地和利口酒调配而成的传统鸡尾酒，又称“亚历珊朵拉”";
<sakura:cocktail:18>.addTooltip(introduce);
<sakura:cocktail:18>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命恢复I")~"、10s§c饥饿II§r和30s§c反胃§rbuff");

//飞行
introduce = "§r由柠檬汁、琴酒和白兰地调配而成的传统鸡尾酒，也叫“云霄”";
<sakura:cocktail:19>.addTooltip(introduce);
<sakura:cocktail:19>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、5s§c漂浮I§r和30s§c反胃§rbuff");

//波菲利浦
introduce = "§r由鸡蛋、白兰地和红葡萄酒调配而成的传统鸡尾酒，也叫“波特霏丽蒲”";
<sakura:cocktail:20>.addTooltip(introduce);
<sakura:cocktail:20>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"急迫I")~"、"~stringEffectInt(10,"夜视")~"和30s§c反胃§rbuff");

//红眼
introduce = "§r由番茄酱、糖、伏特加和啤酒调配而成的传统鸡尾酒";
<sakura:cocktail:21>.addTooltip(introduce);
<sakura:cocktail:21>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命提升I")~"、"~stringEffectInt(10,"夜视")~"和30s§c反胃§rbuff");

//汽酒
introduce = "§r由苏打水和红/白葡萄酒调配而成的流行鸡尾酒，原型原名Spritzer，译为“斯普瑞兹”";
<sakura:cocktail:22>.addTooltip(introduce);
<sakura:cocktail:22>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"夜视")~"和30s§c反胃§rbuff");

//潘趣酒
introduce = "§r由柠檬汁、糖和啤酒调配而成的流行鸡尾酒，原名Panaché，译为“柠檬汽酒”";
<sakura:cocktail:23>.addTooltip(introduce);
<sakura:cocktail:23>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和I")~"、5s§c漂浮I§r和30s§c反胃§rbuff");

//血腥玛丽
introduce = "§r一种著名传统鸡尾酒，游戏中由橙汁和伏特加调配而成（实际配方应该是和螺丝刀写反了）";
<sakura:cocktail:24>.addTooltip(introduce);
<sakura:cocktail:24>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"力量II")~"和30s§c反胃§rbuff");

//螺丝起子
introduce = "§r一种传统鸡尾酒，也叫螺丝起子，游戏中由柠檬汁、盐、黑胡椒、番茄酱和伏特加调配而成（实际配方应该是和血腥玛丽写反了）";
<sakura:cocktail:25>.addTooltip(introduce);
<sakura:cocktail:25>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命提升I")~"、"~stringEffectInt(10,"伤害吸收")~"、"~stringEffect("10","力量I")~"和30s§c反胃§rbuff");

//清酒马提尼
introduce = "§r由清酒和利口酒调配而成的日本风味鸡尾酒，“鸡尾酒之王”马提尼/马天尼的日本风味变种，也叫萨开天尼";
<sakura:cocktail:26>.addTooltip(introduce);
<sakura:cocktail:26>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"生命提升I")~"、"~stringEffectInt(10,"生命恢复I")~"、"~stringEffect("0.1","瞬间治疗I")~"和30s§c反胃§rbuff");

//Boilermaker
introduce = "§r由啤酒和威士忌调配而成的传统鸡尾酒，也叫锅炉厂鸡尾酒";
<sakura:cocktail:27>.addTooltip(introduce);
<sakura:cocktail:27>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和I")~"、"~stringEffectInt(10,"急迫I")~"和30s§c反胃§rbuff");

//啤酒玛格丽塔
introduce = "§r由柠檬汁、啤酒和利口酒调配而成的著名传统鸡尾酒，玛格丽塔的变种之一";
<sakura:cocktail:28>.addTooltip(introduce);
<sakura:cocktail:28>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和I")~"、"~stringEffectInt(10,"速度I")~"和30s§c反胃§rbuff");

//长岛冰茶
introduce = "§r由伏特加、朗姆酒、琴酒、利口酒和龙舌兰，再加入可可豆和柠檬汁调配而成的传统鸡尾酒";
<sakura:cocktail:29>.addTooltip(introduce);
<sakura:cocktail:29>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"金色生命I")~"和30s§c反胃§rbuff");

//海波
introduce = "§r由苏打水加威士忌调配而成的传统鸡尾酒，原型为日本流行的ハイボール（haibōru），也叫威士忌嗨棒";
<sakura:cocktail:30>.addTooltip(introduce);
<sakura:cocktail:30>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//传送走廊
introduce = "§r由苏打水、柠檬汁、薄荷和朗姆酒调配而成的鸡尾酒";
<sakura:cocktail:31>.addTooltip(introduce);
<sakura:cocktail:31>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和I")~"、"~stringEffectInt(10,"急迫I")~"、"~stringEffect("10","力量I")~"和30s§c反胃§rbuff");

//毒刺
introduce = "§r由白葡萄酒、薄荷和利口酒调配而成的经典鸡尾酒，又称史汀格、史丁格";
<sakura:cocktail:32>.addTooltip(introduce);
<sakura:cocktail:32>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"毒药")~"和30s§c反胃§rbuff");

//尼格罗尼
introduce = "§r由利口酒、琴酒和§c红§r葡萄酒调配而成的经典鸡尾酒，也叫尼克洛尼";
<sakura:cocktail:33>.addTooltip(introduce);
<sakura:cocktail:33>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"抗性提升I")~"、"~stringEffectInt(5,"金色生命I")~"和30s§c反胃§rbuff");

//古典酒
introduce = "§r由威士忌、水、糖和朗姆酒调配而成的著名经典鸡尾酒，又称古典酒";
<sakura:cocktail:34>.addTooltip(introduce);
<sakura:cocktail:34>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffectInt(10,"急迫I")~"、"~stringEffect("10","夜视")~"和30s§c反胃§rbuff");

//威士忌酸
introduce = "§r由柠檬汁、糖和威士忌调配而成的经典鸡尾酒，也叫威士忌沙瓦";
<sakura:cocktail:35>.addTooltip(introduce);
<sakura:cocktail:35>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffectInt(10,"急迫I")~"和30s§c反胃§rbuff");

//琴蕾
introduce = "§r由柠檬汁、苏打水和琴酒调配而成的经典鸡尾酒，也叫吉姆雷特";
<sakura:cocktail:36>.addTooltip(introduce);
<sakura:cocktail:36>.addTooltip("§r·饮下后获得"~stringEffectInt(20,"速度I")~"、"~stringEffectInt(20,"急迫I")~"和30s§c反胃§rbuff");

//龙舌兰日出
introduce = "§r由橙汁、糖和龙舌兰调配而成的著名经典鸡尾酒，也叫特基拉日出";
<sakura:cocktail:37>.addTooltip(introduce);
<sakura:cocktail:37>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度I")~"、"~stringEffect("0.1","瞬间治疗")~"和30s§c反胃§rbuff");

//飞蝗
introduce = "§r由柠檬汁、薄荷、啤酒和利口酒调配而成的经典鸡尾酒，也叫飞天蚱蜢";
<sakura:cocktail:38>.addTooltip(introduce);
<sakura:cocktail:38>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"速度II")~"、"~stringEffectInt(10,"跳跃提升I")~"和30s§c反胃§rbuff");

//蛋奶酒
introduce = "§r由牛奶、鸡蛋、糖和威士忌调配而成的经典圣诞节代表性饮品";
<sakura:cocktail:39>.addTooltip(introduce);
<sakura:cocktail:39>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"蝎毒I")~"和30s§c反胃§rbuff");

//天蝎
introduce = "§r由白兰地、柠檬汁、橙汁、糖和朗姆酒调配而成的经典鸡尾酒，也叫天蝎座";
<sakura:cocktail:40>.addTooltip(introduce);
<sakura:cocktail:40>.addTooltip("§r·饮下后获得"~stringEffectInt(10,"饱和I")~"、"~stringEffectInt(10,"力量I")~"和30s§c反胃§rbuff");

//莫斯科骡子
introduce = "§r由柠檬汁、苏打水、柠檬和伏特加调配而成的著名经典鸡尾酒，也叫莫斯科之骡、莫斯科佬";
<sakura:cocktail:41>.addTooltip(introduce);
<sakura:cocktail:41>.addTooltip("§r·饮下后§4只会§r获得30s§c反胃§rbuff");

<sakura:cocktail:*>.addTooltip("§r·重复使用以§a§o延长§r其他buff时间并§e§o重置§r§c反胃§r效果");

//===山猪之悲伤===
//玛格丽塔
<sakura:cocktail:2>.addTooltip("§m§o·然而它并不能给你回血回蓝");
//血腥玛丽
<sakura:cocktail:24>.addTooltip("§m§o·然而它并不能让你在血月提升速度和伤害");
//螺丝起子
<sakura:cocktail:25>.addTooltip("§m§o·然而它并不能给你增加穿透类弹幕的伤害");
//古典酒
<sakura:cocktail:34>.addTooltip("§m§o·然而它并不能给你增加饰品和套装奖励的伤害");
//龙舌兰日出
<sakura:cocktail:37>.addTooltip("§m§o·然而它并不能让你在白天增加伤害、击退和防御");
//莫斯科骡子
<sakura:cocktail:41>.addTooltip("§m§o·然而它并不能增加你的伤害、击退和暴击率");

<sakura:cocktail:*>.addTooltip("§4§l现实中请适量饮酒！未成年人禁止饮酒！！");

function stringEffect(time as string,effectName as string) as string{
    return time~"s§6"~effectName~"§r";
}

function stringEffectInt(time as int,effectName as string) as string{
    return stringEffect(time as string,effectName);
}

function stringEffectIntENG(time as int,effectName as string) as string{
    return "§6" ~ effectName~" §rfor "~(time as string)~" s";
}

<sakura:bottle_alcoholic:*>.addAdvancedTooltip(
    function(item){
        var amountData as IData = item.getCertainNBT(["amount"]);
        if(isNull(amountData)) return "§3剩余酒量：§r§b5/5§r" ;
        return "§3剩余酒量：§r§b"~(5 - amountData.asInt())~"";
    }
);

$expand IItemStack$getCertainNBT(nbtString as string[]) as IData{

    var nbt as IData = this.tag;
    if(isNull(nbt)) return null;

    var returnNBT as IData = nbt;
    if(isNull(nbtString)||nbtString.length == 0) return returnNBT;

    for i in 0 .. nbtString.length{
        if(isNull(returnNBT.memberGet(nbtString[i]))) return null;
        returnNBT = returnNBT.memberGet(nbtString[i]);
    }

    return returnNBT;
}