装配控制器

导包

import mods.pneumaticcraft.assembly;

移除配方

mods.pneumaticcraft.assembly.removeLaserRecipe(IItemStack output);   //根据输出物品移除指定装配程序:激光的配方
mods.pneumaticcraft.assembly.removeDrillRecipe(IItemStack output);   //根据输出物品移除指定装配程序:钻头的配方
mods.pneumaticcraft.assembly.removeDrillLaserRecipe(IItemStack output);   //根据输出物品移除指定装配程序:钻头和激光的配方
mods.pneumaticcraft.assembly.removeAllLaserRecipes();   //移除所有装配程序:激光的配方
mods.pneumaticcraft.assembly.removeAllDrillRecipes();   //移除所有装配程序:钻头的配方
mods.pneumaticcraft.assembly.removeAllDrillLaserRecipes();   //移除所有装配程序:钻头和激光的配方

//例子
mods.pneumaticcraft.assembly.removeLaserRecipe(<pneumaticcraft:aphorism_tile>);  
mods.pneumaticcraft.assembly.removeDrillRecipe(<pneumaticcraft:pressure_chamber_valve>);

添加配方

mods.pneumaticcraft.assembly.addLaserRecipe(IItemStack input, IItemStack output);   //添加基于装配程序:激光的配方，后两项依次为输入，输出
mods.pneumaticcraft.assembly.addDrillRecipe(IItemStack input, IItemStack output);  //添加基于装配程序:钻头的配方，后两项依次为输入，输出

//例子
mods.pneumaticcraft.assembly.addLaserRecipe(<ic2:crafting:2>, <contenttweaker:rftdianlu>);
mods.pneumaticcraft.assembly.addDrillRecipe(<contenttweaker:rft_frame>, <rftools:machine_frame>);

如需添加基于装配程序:钻头和激光的配方，可以通过写基于钻头的配方A生产B，并写基于激光的配方B生产C，crt将会自动识别并添加基于装配程序:钻头和激光的配方。

爆炸合成

导包

import mods.pneumaticcraft.explosioncrafting;

移除配方

mods.pneumaticcraft.explosioncrafting.removeRecipe(IIngredient output);   //根据输出物品移除指定配方
mods.pneumaticcraft.explosioncrafting.removeAllRecipes();   //移除所有配方

//例子
mods.pneumaticcraft.explosioncrafting.removeRecipe(<pneumaticcraft:ingot_iron_compressed>);

添加配方

mods.pneumaticcraft.explosioncrafting.addRecipe(IOreDictEntry input, IItemStack output, int loss_rate);   //后三项数值依次为输入，输出，失败损失物品概率

//例子
mods.pneumaticcraft.explosioncrafting.addRecipe(<ic2:ingot>, <ic2:crafting:3>, 80);

导热框架冷却

导包

import mods.pneumaticcraft.heatframecooling;

移除配方

mods.pneumaticcraft.heatframecooling.removeRecipe(IIngredient output);   //根据产出物品移除指定配方
mods.pneumaticcraft.heatframecooling.removeAllRecipes();   //移除所有配方

//例子
mods.pneumaticcraft.heatframecooling.removeRecipe(<minecraft:obsidian>);

添加配方

mods.pneumaticcraft.heatframecooling.addRecipe(IOreDictEntry input, IItemStack output);   //后两项依次为输入物品/矿辞，输出物品

//例子
mods.pneumaticcraft.heatframecooling.addRecipe(<minecraft:slime_ball>, <minecraft:snow_ball>);

液体压缩机可用燃料

导包

 import mods.pneumaticcraft.liquidfuel;

移除配方

mods.pneumaticcraft.liquidfuel.removeFuel(ILiquidStack fluid);   //移除指定液体作为液体压缩机燃料
mods.pneumaticcraft.liquidfuel.removeAllFuels();//移除所有液体压缩机可用燃料

//例子
mods.pneumaticcraft.liquidfuel.removeFuel(<liquid:lpg>);

添加配方

mods.pneumaticcraft.liquidfuel.addFuel(ILiquidStack fluid, double mlPerBucket);   //后两项依次为输入的液体，每桶液体可以产生多少ml空气

//例子
mods.pneumaticcraft.liquidfuel.addFuel(<liquid:water>, 16000);

塑料混合器

导包

import mods.pneumaticcraft.plasticmixer;

移除配方

mods.pneumaticcraft.plasticmixer.removeRecipe(ILiquidStack fluid);   //删除指定液体作为输入的配方
mods.pneumaticcraft.plasticmixer.removeAllRecipes();   //移除所有配方

//例子
mods.pneumaticcraft.plasticmixer.removeRecipe(<liquid:plastic>);

添加配方

mods.pneumaticcraft.plasticmixer.addRecipe(ILiquidStack liquid, IItemStack stack, int temperature);   //添加可以进行双向转换的配方，后三项依次为对应液体，对应物品，所需温度(开尔文)
mods.pneumaticcraft.plasticmixer.addSolidifyOnlyRecipe(ILiquidStack liquidInput, IItemStack itemOutput);   //添加仅允许凝固的配方，后两项依次为输入液体，输出物品
mods.pneumaticcraft.plasticmixer.addMeltOnlyRecipe(IItemStack itemInput, ILiquidStack fluidOutput, int temperature);   //添加仅允许融化的配方，后三项依次为输入物品，输出液体，所需温度(开尔文)

//例子
mods.pneumaticcraft.plasticmixer.addRecipe(<liquid:lava> * 100, <minecraft:concrete>, 573);
mods.pneumaticcraft.plasticmixer.addSolidifyOnlyRecipe(<liquid:oil> * 2000, <pneumaticcraft:plastic>);
mods.pneumaticcraft.plasticmixer.addMeltOnlyRecipe(<pneumaticcraft:plastic>, <liquid:oil> * 100, 473);

压力室配方

导包

import mods.pneumaticcraft.pressurechamber;

移除配方

mods.pneumaticcraft.pressurechamber.removeRecipe(IItemStack[] outputs);   //根据产出物品移除配方
mods.pneumaticcraft.pressurechamber.removeAllRecipes();   //移除所有配方

//例子
mods.pneumaticcraft.pressurechamber.removeRecipe([<pneumaticcraft:ingot_iron_compressed>]);

添加配方

mods.pneumaticcraft.pressurechamber.addRecipe(IIngredient[] inputs, double pressure, IItemStack[] outputs);   //后三项依次为输入物品组，所需压力值，产出物品组

//例子
mods.pneumaticcraft.pressurechamber.addRecipe([<extrabotany:gildedmashedpotato>,<botania:manaresource:7>,<extrabotany:nightmarefuel> * 3], 5.0, [<extrabotany:material:5>]);

精炼厂配方

导包

import mods.pneumaticcraft.refinery;

移除配方

mods.pneumaticcraft.refinery.removeRecipe(IIngredient[] outputs);   //移除找到的以指定液体为输出的配方
mods.pneumaticcraft.refinery.removeRecipes(IIngredient input);   //移除找到的以指定液体为输入的配方
mods.pneumaticcraft.refinery.removeAllRecipes();   //移除所有配方

添加配方

mods.pneumaticcraft.refinery.addRecipe(ILiquidStack input, ILiquidStack[] outputs);   //添加默认以最小温度为373开尔文的配方，后两项依次为液体输入，液体组输出
mods.pneumaticcraft.refinery.addRecipe(int minimumTemperature, ILiquidStack input, ILiquidStack[] outputs);   //(需版本大于等于V0.9.0)，后三项依次为所需最小温度(开尔文)，液体输入，液体组输出

//例子
mods.pneumaticcraft.refinery.addRecipe(<liquid:water> * 10, [<liquid:lava> * 2, <liquid:oil> * 5]);
mods.pneumaticcraft.refinery.addRecipe(473, <liquid:water> * 10, [<liquid:lava> * 2, <liquid:oil> * 5, <liquid:lpg> * 2, <liquid:infinity_metal> * 5]);

热气动加工机配方

导包

import mods.pneumaticcraft.thermopneumaticprocessingplant;

移除配方

mods.pneumaticcraft.thermopneumaticprocessingplant.removeRecipe(IIngredient output);   //根据液体输出移除配方
mods.pneumaticcraft.thermopneumaticprocessingplant.removeAllRecipes();   //移除所有配方

//例子
mods.pneumaticcraft.thermopneumaticprocessingplant.removeRecipe(<liquid:lpg>);

添加配方

//后五项依次为液体输入，物品输入(可以为null)，所需压力，所需温度(开尔文)，液体输出
mods.pneumaticcraft.thermopneumaticprocessingplant.addRecipe(ILiquidStack liquidInput, IItemStack itemInput, double pressure, double temperature, ILiquidStack output);
//后四项依次为物品输入，所需压力，所需温度(开尔文)，液体输出
mods.pneumaticcraft.thermopneumaticprocessingplant.addRecipe(IItemStack itemInput, double pressure, double temperature, ILiquidStack output);

//例子
mods.pneumaticcraft.thermopneumaticprocessingplant.addRecipe(<liquid:oil> * 10, null, 3.0, 473, <liquid:lava> * 5);
mods.pneumaticcraft.thermopneumaticprocessingplant.addRecipe(<minecraft:netherrack>, 1.5, 573, <liquid:lava> * 50);

空中界面识别经验流体

该功能可以让空中界面将其他任意流体识别为经验，默认情况下该部分只会识别末影接口，循环，开放式方块，热力膨胀，工业先锋中的液态经验

导包

import mods.pneumaticcraft.xpfluid;

移除流体

mods.pneumaticcraft.xpfluid.removeXPFluid(ILiquidStack fluid);
mods.pneumaticcraft.xpfluid.removeAllXPFluids();   //移除所有流体

//例子
mods.pneumaticcraft.xpfluid.removeXPFluid(<liquid:xpjuice>);

添加流体

mods.pneumaticcraft.xpfluid.addXPFluid(ILiquidStack fluid, double ratio);   //后两项依次为可用流体，每mb液体玩家可获得xp数值

//例子
mods.pneumaticcraft.xpfluid.addXPFluid(<liquid:lpg>, 10);