内容来自mot官方文档（TComplement - CraftTweaker Documentation (blamejared.com)）

高炉合金

import mods.tcomplement.highoven.HighOven; //导包（这个是必须的，如果需要这个包的配方都在一个zs里那你只用写一个）
import mods.tcomplements.highoven.MixRecipeBuilder; //函数

//以下是官方写法
var builder = HighOven.newMixRecipe(<liquid:steel> * 72, <liquid:iron> * 144, 1350); //“builder”是变量名称，可以改的
builder.addOxidizer(<minecraft:redstone>, 95);
builder.addReducer(<minecraft:glowstone>, 5);
builder.addPurifier(<ore:dustCoal>, 50);
builder.addPurifier(<minecraft:nether_star>, 0);
builder.register();

//以下是链式调用写法
HighOven.newMixRecipe(<liquid:steel> * 288, <liquid:crude_steel> * 288, 750) //产出流体，输入流体，温度
    .addOxidizer(<ore:dustChrome>, 80) //氧化剂，概率（百分比）
    .addReducer(<ore:dustCoal>, 90) //还原剂，概率
    .addPurifier(<contenttweaker:iron_sand>, 100) //净化剂，概率
    .register();

已有合金配方修改

import mods.tcomplement.highoven.HighOven; //导包（这个是必须的）
import mods.tcomplement.highoven.MixRecipeManager; //函数

//链式调用写法（分号写在最后一行即可）
HighOven.manageMixRecipe(<liquid:knightslime>,<liquid:iron>) //输出流体，输入流体
    .removeOxidizer() //移除氧化剂（事实上骑士史莱姆没有氧化剂，所以根本不需要这一行）
    .addOxidizer(<ore:dustChrome>, 80) //添加氧化剂，概率
    .removeReducer(<tconstruct:edible:2>) //移除还原剂
    .addReducer(<tconevo:material:1>,40) //添加还原剂，概率
    .removePurifier(<minecraft:gravel>) //移除净化剂
    .addPurifier(<tconstruct:seared>,50) //添加净化剂，概率
    .addPurifier(<minecraft:stone>,100); //添加净化剂，概率

燃料添加与移除

import mods.tcomplement.highoven.HighOven;

HighOven.removeFuel(<minecraft:coal:1>); //移除

HighOven.addFuel(<minecraft:hay_block>, 3600, 5); //添加燃料，燃烧时间，比例

物品融化

import mods.tcomplement.highoven.HighOven;

HighOven.removeMeltingOverride(<liquid:iron>); //移除

HighOven.addMeltingOverride(<liquid:steel> * 144, <ore:ingotIron>, 2567); //熔融液体，熔融物品，温度（可不写）
//注意，高炉熔融和匠魂炉熔融的添加是单箭头的
//也就是匠魂的熔融配方高炉可以用，但是高炉的熔融匠魂不能用

高炉加热

import mods.tcomplement.highoven.HighOven;

HighOven.removeHeatRecipe(<liquid:steam>); //移除

HighOven.addHeatRecipe(<liquid:iron> * 144, <liquid:lava> * 1000, 1450); //加热后流体，加热前流体，温度
//其实和精炼差不多，但是原本会有一个水加热成水蒸气的配方