猴子看了都会的Mekatweaker教程 - Mekatweaker - MC百科|最大的Minecraft中文MOD百科

本篇教程由作者设定未经允许禁止转载。

开始前的bb

因为mc百科给出的这些提升太过于“朴素”了

想用的人看都看不懂，也不知道这些语句是干什么的，也不提供wiki链接，我自己看看wiki，源码与md是这个md不是骂人的tmd的md

与大量实测后确定这些语句是怎么用的了，才来写这篇教程

参考文献

crt官方文档

Metallurgic Infuser - CraftTweaker Documentation (blamejared.com)

git的md

https://github.com/Lorexe/MekaTweaker/blob/master/README.md

气体的wiki：https://www.curseforge.com/minecraft/mc-mods/mekatweaker/pages/gas

灌注类型的wiki: https://www.curseforge.com/minecraft/mc-mods/mekatweaker/pages/infuser-type

源码的链接我就不放了，反正你看不懂

正文

灌注类型

介绍灌注类型与乱写的剧情部分

这是一个治金灌注机的gui

这个就是放灌注类气体的槽位，而原版只能放一下这些灌注类气体，分别是

锡：

煤炭：

红石：

钻石：

黑曜石：

生物质：

真的是太难受了。

作为一名魔改人，你在想万能的crt啊，我们需要你的帮助，就只能放这么一点放灌注类气体，我们怎么让那些肝帝肝爆啊。

这时，Mekatweaker的作者看不下去了，为大家制造出了mod

提供了crt方法......

他给出了添加灌注类气体的crt方法十分简单

灌注类气体创建部分

灌注类气体创建

小贴士：红色部分是填参数部分

//导包

#priority 100

#loader mekatweaker

import mods.mekatweaker.InfuserType;

//内容

InfuserType.addType("名字");（注：要使用英文大写！！！）

灌注类气体的实例

//导包
#priority 100
#loader mekatweaker
import mods.mekatweaker.InfuserType;
//我们要创建一个叫做钋的灌注类气体
InfuserType.addType("POLONIUM");

好的写玩了进游戏看看

通过crt的/ct infuseTypes指令

已经注册了的灌注类气体会被输出在crafttweaker.log

物品生华为灌注类气体部分

物品生华为灌注类气体

好的，你既然已经可以注册灌注类气体了

那么如何让他生华成气体呢？

例如这样：

只需要短短的一句就行

InfuserType.addTypeObject(以尖括号引用形式的物品ID, "大写的灌注类型名称", 他的数量);

没错，连导包都不需要这是因为mek与crt本身就有联动

物品生华为灌注类气体实例

//我想让花岗岩(<minecraft:stone:1>)生华后变成钋("POLONIUM")10个mek标准灌注类型单位

//ps：一点也不科学！！！

//那么需要这样写

InfuserType.addTypeObject(<minecraft:stone:1>, "POLONIUM", 10);

好了，我们上游戏看看

为灌注类气体材质添加部分

为灌注类气体材质添加方法

但是没有材质啊，怎么办？

你只需要在mc的目录下

这个文件打开

继续打开

将你的材质放在infuse文件里

名字命名为:你取的名字.png

请放入16x16的材质！

为灌注类气体材质添加的实例

好的上游戏看看

好耶成功的为灌注类添加了材质

但是！蛙趣！没有汉化！我要马上汉化！

我知道你很急，但是你先别急。

灌注类气体汉化部分

为灌注类气体汉化方法

汉化方法是

先回到mc的目录底下

打开这个文件

就是这个文件

你能看到，只有一个en_us.lang

你要自己创建一个文本文档，然后命名为zh_cn.lang

打开，把下面说的写在zh_cn.lang里

格式是：infuse.小写的你写的名字=中文名

为灌注类气体汉化的实例

infuse.polonium=钋

这样后进游戏看看

完美！

这样就可以快乐的创建灌注类型了，那么应该怎么让他合成物品呢？

添加治金灌注机的合成表部分

添加治金灌注机的合成表方法

只需要短短的一句就行了,不用导包

mods.mekanism.infuser.addRecipe("大写的灌注类型名称", 需要的mek标准灌注类型单位的数量, 输入的物品ID，输出的物品ID);

注意！物品以尖括号引用形式的物品ID

添加治金灌注机的合成表实例

我想让钻石（<minecraft:diamond>）通过灌注10个mek标准灌注类型单位的钋（POLONIUM）变成传送核心（<mekanism:teleportationcore>）

那么应该这样写

mods.mekanism.infuser.addRecipe("POLONIUM", 10, <minecraft:diamond>, <mekanism:teleportationcore>);

JEI，成功识别

测试也没有问题不是假合成，好了如果你看到这里你已经完全学会如何写创建灌注类型，与添加灌注类型的生华还有添加治金灌注机的合成表

接下来就是创建气体了！

创建气体

介绍气体与乱写的剧情部分

这些是1.12.2mek自己创建的气体

这是一个气体储罐

气体储罐里面可以放气体，但是只能放这么点气体

ps：被打马赛克的是流体

真的是太难受了

还有

总是有1.12.2的玩家在叫，啊，我想要玩mekv10版本！！！

但是mekv10版本没有1.12.2，他们只能去1.16.5或者更高版本去玩。

真的是太难受了，有一些1.12.2作者在想，就不能在1.12.2玩到mekv10吗，既然mek的作者不做，那我们就自己搞！

crt可是万能的！但是一出来，看到要创建气体就没办法了，crt本体与cot并没有与mek创建气体的联动

这时，Mekatweaker的作者看不下去了，为大家制造出了mod

他给出了注册气体的crt方法.....

本来是有两个创建方法的但是另一个.......

额，怎么说呢，就是有点像脱裤子放屁要在原有的液体上添加气体

所以，本教程不会提这个crt方法

创建气体教程部分

创建气体方法

一个合法的注册脚本共分为3部分导包，声明变量与添加3个部分

//导包

#priority 100

#loader mekatweaker

import mods.mekatweaker.Gas;

import mods.mekatweaker.GasFactory;

//声明变量

var 你写的名字= GasFactory.createGas("名字");

//名字要写英文

//添加

你写的名字.setUnlocalizedName("你写的名字");//这一条没有为什么

你写的名字.setColorize(true);//是否设置颜色，不要动！

//这里的颜色是指在管道的颜色

如果填false有小概率导致崩溃，更多情况是

你写的名字.setColor(0x16进制的颜色代码);//管道的颜色,要填入16进制的颜色代码

你写的名字.setNeedFluid(true或false);//是否添加流体，比如盐水，有这些

但是我要提醒一下

但是这个mod创建的流体会有亿点点小问题

倒出来的流体会这样

所以，不建议用Mekatweaker创建流体

你写的名字.needBucket();//如果添加流体的话是否添加流体桶，如果不想加就不写

你写的名字.setIcon("blocks/你写的名字");//没有为什么,不想报错或材质黑紫块就得这样写

你写的名字.setIconFlowing（"blocks/fluid+你写的名字"）//材质的放置地点，下面的液体材质添加方法会说到

你写的名字.register();//完成注册

创建气体实例

创建气体实例1

不创建流体的实例

我想创建六氟化铀气体那么应该这样写

//导包
#priority 100
#loader mekatweaker
import mods.mekatweaker.Gas;
import mods.mekatweaker.GasFactory;
//声明变量
var Uranium_Hexafluoride= GasFactory.createGas("Uranium_Hexafluoride");
//内容
Uranium_Hexafluoride.setUnlocalizedName("Uranium_Hexafluoride");
Uranium_Hexafluoride.setColorize(true);
Uranium_Hexafluoride.setColor(0x62744a);
Uranium_Hexafluoride.setNeedFluid(false);//此行可省略
Uranium_Hexafluoride.setIcon("blocks/Uranium_Hexafluoride");
Uranium_Hexafluoride.register();

好的上号看看

OK,成功创建了

创建气体实例2

创建流体的实例

我想创建氦气体那么应该这样写

//导包
#priority 100
#loader mekatweaker
import mods.mekatweaker.Gas;
import mods.mekatweaker.GasFactory;
//声明变量
var Helium= GasFactory.createGas("Helium");
//内容
Helium.setUnlocalizedName("Helium");
Helium.setColorize(true);
Helium.setColor(0xf15544);
Helium.setNeedFluid(true);
Helium.needBucket()；
Helium.setIcon("blocks/Helium");
Helium.setIconFlowing("blocks/fluidHelium");
Helium.register();

ok,上游戏看看

好极了!成功注册了。

但是！它们都没有材质。

为气体材质添加材质部分

为气体材质添加材质方法

这个就比较麻烦了我们需要修改json

但是要修改哪里的json呢？

跟我点

来到mc目录下

打开这个文件

打开它

就是fluids.json这个文件了

作者已经给出了两个实例但是我们不用鸟他

直接在这里加逗号继续写就ok了

格式为

        "你写的名字": {
            "model": "forge:fluid",
            "custom": { "fluid": "你写的名字" }
        }

然后将气体材质放在

跟我点

继续点这里

继续打开

将气体的材质放在这里

材质名称为：
你写的名字.png

为气体材质添加材质的实例

//这是氦气的json

      "Helium": {
            "model": "forge:fluid",     
             "custom": { "fluid": "Helium" }      
          }

//这是建六氟化铀json

        "Uranium_Hexafluoride": {
            "model": "forge:fluid",            
            "custom": { "fluid": "Uranium_Hexafluoride" }
        }

这是我自己画的材质命名为了氦气（Helium.png），六氟化铀（Uranium_Hexafluoride.png）

好的，进游戏看看

好极了!材质成功的被加载了

接下来就是汉化了

气体材汉化部分

气体材汉化方法

汉化方法是

先回到mc的目录底下

打开这个文件

就是这个文件

如果你刚才看了上面的为灌注类气体汉化方法的话，那么你看到的就是下面这张图一样有zh_cn.lang文件

如果你没有看上面的为灌注类气体汉化方法的话你要自己创建一个文本文档，然后命名为zh_cn.lang

打开，把下面说的写在zh_cn.lang里

气体的格式是：gas.你写的名字=中文名
流体的格式是：fluid.你写的名字=中文名

气体材汉化实例

那么我们要汉化氦（Helium）与六氟化铀（Uranium_Hexafluoride），但是氦（Helium）有创建流体所以氦要多写一条

gas.Helium=氦
fluid.Helium=液态氦
gas.Uranium_Hexafluoride=六氟化铀

写在zh_cn.lang里

打开游戏看看

好了，看到这里相信你已经学会了如何写创建灌注类型，与添加灌注类型的生华还有添加治金灌注机的合成表，还有如何创建气体，感谢你的浏览，陌生人。