该教程汉化自：https://github.com/thedarkcolour/Future-MC/wiki

蜜蜂

添加或移除有效花朵以进行授粉。

1.12 的导入是

import mods.futuremc.Bee;

允许一朵花；

允许蜜蜂从该方块中收集花粉，甚至不必是一朵花。

import mods.futuremc.Bee;
import crafttweaker.block.IBlockState;

Bee.addFlower(<blockstate:actuallyadditions:block_black_lotus>);

禁止一朵花；

防止蜜蜂从这朵花中搜索和收集花粉。

import mods.futuremc.Bee;
import crafttweaker.block.IBlockState;
   
Bee.removeFlower(<minecraft:red_flower>);

清除默认值；

如果你想彻底检查蜜蜂可以授粉的花，那么在添加你自己的配方之前使用此功能。

mods.futuremc.Bee.clearValidFlowers();

烟熏炉和高炉

添加配方；

烟熏炉。

// mods.futuremc.Smoker.addRecipe(IItemStack input, IItemStack output);
mods.futuremc.Smoker.addRecipe(<minecraft:pumpkin>, <minecraft:seeds>); // 南瓜 -> 种子

高炉。

// mods.futuremc.BlastFurnace.addRecipe(IItemStack input, IItemStack output);
mods.futuremc.BlastFurnace.addRecipe(<minecraft:cobblestone>, <futuremc:smooth_stone>); // 圆石 -> 平滑石头

移除配方；

烟熏炉。

// mods.futuremc.Smoker.removeRecipe(IItemStack input);
mods.futuremc.Smoker.removeRecipe(<minecraft:beef>); // 移除烹饪牛排的配方

高炉。

// mods.futuremc.BlastFurnace.removeRecipe(IItemStack input);
mods.futuremc.BlastFurnace.removeRecipe(<minecraft:diamond_ore>); // 移除熔炼钻石矿的配方

篝火

添加配方；

// mods.futuremc.Campfire.addRecipe(IItemStack input, IItemStack output, int duration);
mods.futuremc.Campfire.addRecipe(<minecraft:cobblestone>, <minecraft:stone>, 1200); // 添加圆石 -> 需要 60 秒才能变成的石头配方。

移除配方；

// mods.futuremc.Campfire.removeRecipe(IItemStack stack);
mods.futuremc.Campfire.removeRecipe(<minecraft:beef>); // 移除在篝火上烹饪生牛肉的配方。

清除默认配方；

在添加配方之前调用它以删除所有默认配方。

mods.futuremc.Campfire.clearRecipes();

堆肥桶

添加有效物品；

将物品（元数据敏感）添加到堆肥桶的有效物品列表中，并有一定的成功率，你还可以使用 IOreDictEntry 而不是 IItemStack。

// mods.futuremc.Composter.addValidItem(IItemStack item, int chance);
mods.futuremc.Composter.addValidItem(<minecraft:stick>, 20);

移除有效物品；

将该物品（元数据敏感）从堆肥桶的有效物品列表中移除。

// mods.futuremc.Composter.removeValidItem(IItemStack item);
mods.futuremc.Composter.removeValidItem(<minecraft:potato>);

改变物品几率；

改变堆肥桶的有效物品（元数据敏感）的成功机会。

// mods.futuremc.Composter.replaceValidItemChance(IItemStack item, int newChance);
mods.futuremc.Composter.replaceValidItemChance(<minecraft:potato>, 100);

清除有效物品；

在你添加配方之前调用这个，以删除所有默认的有效物品。

mods.futuremc.Campfire.clearValidItems();

锻造台

将配方添加到锻造台。

1.12 的导入是

import mods.futuremc.SmithingTable;

1.15 的导入是

import futuremc.crafttweaker.SmithingTable;

添加配方（1.12.2）

将一个配方添加到锻造台中，参数：

input：IItemStack - 物品的类型（id）。

material：IItemStack - 材料和它的数量（id，元数据，数量）。

result：IItemStack - 从输入的物品NBT中输出物品（id）。

import mods.futuremc.SmithingTable;

SmithingTable.addRecipe(<minecraft:diamond_pickaxe>, <futuremc:netherite_ingot>, <futuremc:netherite_pickaxe>);

添加配方（1.15）

将一个配方添加到铁匠表中，参数：

name: 字符串 - 要添加的配方的名称（例如："netherite_pickaxe_from_smithing"）。

result:  IItemStack - 输入升级的产物（例如：Netherite Pickaxe）。

input:  IIngredient - 要升级的物品（例如：Diamond Pickaxe）。

material:  IIngredient - 用来升级的材料（例如：下届合金）。

materialCost:  int - 升级物品所需的材料数量（例如：1）。

import futuremc.crafttweaker.SmithingTable;

SmithingTable.addRecipe("netherite_pickaxe_from_smithing", <item:futuremc:netherite_pickaxe>, <item:minecraft:diamond_pickaxe>, <item:futuremc:netherite_ingot>, 1);

移除配方（1.12.2）

import mods.futuremc.SmithingTable;
SmithingTable.removeRecipe(<minecraft:diamond_pickaxe>, <futuremc:netherite_ingot>);

清除默认配方（1.12.2）

import mods.futuremc.SmithingTable;
SmithingTable.clearDefaults();

1.15的移除配方和清除默认配方都没有。

切石机

添加配方；

添加配方。

// mods.futuremc.Stonecutter.addOutput(IItemStack input, IItemStack outputs);
mods.futuremc.Stonecutter.addOutput(<minecraft:stone>, <minecraft:furnace>); // 添加熔炉作为切割石头的配方

为每个输出添加多个配方的快捷功能。

// mods.futuremc.Stonecutter.addOutputs(IItemStack input, IItemStack... outputs);
mods.futuremc.Stonecutter.addOutputs(<minecraft:stone>, <minecraft:glass>, <minecraft:sandstone>); // 添加玻璃和砂岩作为切割石头的配方

移除配方；

// mods.futuremc.Stonecutter.removeOutputs(IItemStack input, IItemStack... outputs);
mods.futuremc.Stonecutter.removeOutputs(<minecraft:stone>, <minecraft:stone_slab>); // 移除将石头切割成半砖的配方

移除有效输入；

// mods.futuremc.Stonecutter.removeAllOutputsForInput(IItemStack input);
mods.futuremc.Stonecutter.removeAllOutputsForInput(<minecraft:stone>); // 移除可切割的石头

清除默认配方；

mods.futuremc.Stonecutter.clearRecipes();