说明：本教程大致属于中文解释说明搬运官方wiki的部分 原地址这里
转了半天发现居然没有凝聚板的魔改教程 那我这就来一个简单说明版本吧
因为我本人也只运用到了基础的修改配方部分 所以未提到的部分我也能力有限x
魔改基于CrT与Botania Tweaks两个模组 请务必都安装好
——————————分割线——————————
魔改第一行需导入Botania Tweaks相关包
import mods.botaniatweaks.Agglomeration;
凝聚板添加配方（其中输入的物品间用英文逗号,隔开 至少设定一个物品 至多未测试）
Agglomeration.addRecipe(<产出物品>,[<输入物品1>,<输入物品2>],需要的魔力值);
Agglomeration.addRecipe(output,inputs.IIngredient[],manaCost);
参考 （钻石+魔力尘+精灵尘=末影珍珠 消耗5000mana）
Agglomeration.addRecipe(<minecraft:ender_pearl>,[<minecraft:diamond>,<botania:manaresource:23>,<botania:manaresource:8>],5000);
删除配方（与添加同理）
Agglomeration.removeRecipe(<输出物品>,[<输入物品>,<输入物品>]);
Agglomeration.removeRecipe(output,inputs.IIngredient[]);
参考（删除泰拉钢配方）
Agglomeration.removeRecipe(<botania:manaresource:4>,[<botania:manaresource:2>,<botania:manaresource>,<botania:manaresource:1>]);
同时 你可以编辑一些其他的属性
例如修改不同的凝聚板基座（原青金石活石方块），给配方不同的合成粒子颜色（泰拉钢默认从蓝到绿）
配方同上 后面多加参数
Agglomeration.addRecipe(<产出物品>,[<输入物品1>,<输入物品2>],需要的魔力值,合成开始的颜色,合成结束的颜色,<凝聚板正下方方块>,<前后左右的方块>,<四个角落的方块>,<结束后正下方替换的方块>,<结束后前后左右替换的方块>,<结束后四角替换的方块>);
Agglomeration.addRecipe(output,inputs.IIngredient[],manaCost,color1,color2,center,edge,corner,centerReplace,edgeReplace,cornerReplace);
参考
Agglomeration.addRecipe(<draconicevolution:draconic_ingot>,
[<draconicevolution:draconium_ingot>*2,<thermalfoundation:material:1024>*2,<thermalfoundation:material:1025>*2,<mekanism:dust:2>],
5000000,0xA439FB,0xFF6600,
<draconicevolution:draconium_block:1>,<botania:storage:4>,<minecraft:beacon>,
<draconicevolution:draconium_block>,null,null);
上述配方如图所示（其中 中间的方块从充能龙块替换成龙块 每合成一次都会转换）
wiki贴出的一张参数表格
参数数值按从上到下顺序添加 用,隔开
| Argument | Default Value | Type | Function |
|---|---|---|---|
| output | (required) | IItemStack | The recipe's output. |
| inputs | (required) | IIngredient[] | The recipe's inputs; the items you put on the plate. |
| manaCost | 500,000 | int | How much mana this recipe costs; the default is equivalent to terrasteel. |
| color1 | 0x0000FF | int | Particle color at the start of the recipe (0xRRGGBB format) |
| color2 | 0x00FF00 | int | Particle color at the end of the recipe (0xRRGGBB format) |
| center | <botania:livingrock> | IIngredient | The blockstate that's directly under the plate. |
| edge | <minecraft:lapis_block> | IIngredient | The blockstate under the four edges of the plate. |
| corner | <botania:livingrock> | IIngredient | The blockstate that's at the four corners of the plate. |
| centerReplace | null | IIngredient | Upon completing the recipe, this block will replace the center of the multiblock. If null (the default value), nothing will be replaced. |
| edgeReplace | null | IIngredient | Ditto, but for the four edges. |
| cornerReplace | null | IIngredient | Ditto, but for the four corners. |
简要翻译
| 对象 | 默认值 | Type | 作用说明 |
|---|---|---|---|
| output | (required) | IItemStack | 配方的输出物品 |
| inputs | (required) | IIngredient[] | 配方的输入物品，你放在凝聚板上的物品 |
| manaCost | 500,000 | int | 消耗多少mana魔力，默认等同于泰拉钢的魔力 |
| color1 | 0x0000FF | int | 合成开始时候的粒子颜色 0xRRGGBB格式（十六进制颜色代码） |
| color2 | 0x00FF00 | int | 合成末尾时候的粒子颜色 0xRRGGBB格式（十六进制颜色代码） |
| center | <botania:livingrock> | IIngredient | 凝聚板下面的方块 |
| edge | <minecraft:lapis_block> | IIngredient | 凝聚板四边方块 |
| corner | <botania:livingrock> | IIngredient | 凝聚板四个角落方块 |
| centerReplace | null | IIngredient | 合成结束后，这个方块会替换开始的方块。如果设为null(默认值)，则不会替换。 |
| edgeReplace | null | IIngredient | 与上述一样 但是是四边的方块 |
| cornerReplace | null | IIngredient | 一样 是四角的方块 |
十六进制颜色可以从ps或者sai的颜色选择里直接查看 或者直接上百度搜也行
如果设定了center 还必须设定edge和corner 即必须设定整个多方块结构 或者保留为默认值
